Binaryworld - InStrRev - A replacement for VB6's InStrRev under VB4 and VB5 ... [ VB -> String ]

' A replacement for the InStrRev function under VB4 and VB5
'
' NOTE: uses the StrReverse function

Function InStrRev(ByVal Text As String, Search As String, _
  Optional ByVal Start As Long = -1, Optional ByVal CompareMethod As _
  VbCompareMethod = vbBinaryCompare) As Long
  Dim Index As Long
  ' reverse the source strings,
  ' so that we can use regular InStr
  Text = StrReverse(Text)
  Search = StrReverse(Search)
  ' we must "reverse" Start too
  If Start < 0 Then
    Start = 1
  Else
    Start = Len(Text) + 1 - Start
  End If

  Index = InStr(Start, Text, Search, CompareMethod)
  If Index Then
    ' adjust the result
    InStrRev = Len(Text) - Index - Len(Search) + 2
  End If
End Function

' A replacement for the StrReverse function for VB4 and VB5

Function StrReverse(ByVal Text As String) As String
  Dim length As Long, index As Long

  length = Len(Text)
  StrReverse = Space$(length)
  For index = 1 To length
    Mid$(StrReverse, length + 1 - index, 1) = Mid$(Text, index, 1)
  Next

End Function