Binaryworld - ShiftLeft - Shift a Long to the left ... [ VB -> Math ]

' Shift to the left of the specified number of times
'
' NOTE: requires Power2()

Function ShiftLeft(ByVal value As Long, ByVal times As Long) As Long
  ' we need to create a mask of 1's corresponding to the
  ' times in VALUE that will be retained in the result
  Dim mask As Long, signBit As Long

  ' return zero if too many times
  If times >= 32 Then Exit Function
  ' return the value if zero times
  If times = 0 Then ShiftLeft = value: Exit Function

  ' this extracts the bit in Value that will become the sign bit
  mask = Power2(31 - times)
  ' this calculates the sign bit of the result
  signBit = CBool(value And mask) And &H80000000
  ' this clears all the most significant times,
  ' that would be lost anyway, and also clears the sign bit
  value = value And (mask - 1)
  ' do the shift to the left, without risking an overflow
  ' and then add the sign bit
  ShiftLeft = (value * Power2(times)) Or signBit
End Function

' Raise 2 to a power
' the exponent must be in the range [0,31]

Function Power2(ByVal exponent As Long) As Long
  Static res(0 To 31) As Long
  Dim i As Long

  ' rule out errors
  If exponent < 0 Or exponent > 31 Then Err.Raise 5

  ' initialize the array at the first call
  If res(0) = 0 Then
    res(0) = 1
    For i = 1 To 30
      res(i) = res(i - 1) * 2
    Next
    ' this is a special case
    res(31) = &H80000000
  End If

  ' return the result
  Power2 = res(exponent)

End Function