Binaryworld - Get full control on the text typed in a TreeView's node ... [ VB -> Controls-TreeView ]

The TreeView control exposes the AfterLabelEdit event to let the programmer validate the text entered in a Node, but there is no way to trap keys as they are typed by the user. This prevents you from discarding unwanted characters while the user types them.

You can work around this problem by subclassing the Edit control that the TreeView control creates when entering the node edit mode. The following code uses the MSGHOOK.DLL library, that you can download from the FileBank on this site, to discard spaces:

Click here to copy the following block

' REQUIRES THE MSGHOOK.DLL LIBRARY

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal _
  hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, _
  lParam As Any) As Long
Private Const TV_FIRST = &H1100
Private Const TVM_GETEDITCONTROL = TV_FIRST + 15

Dim WithEvents TVHook As MsgHook

' start subclassing of the Edit control used when in edit mode

Private Sub TreeView1_BeforeLabelEdit(Cancel As Integer)
  Dim editHWnd As Long
  ' get the handle of the TreeView's Edit control
  editHWnd = SendMessage(TreeView1.hWnd, TVM_GETEDITCONTROL, 0, ByVal 0&)
  ' subclass it
  TVHook.StartSubclass editHWnd
End Sub

Private Sub TreeView1_AfterLabelEdit(Cancel As Integer, NewString As String)
  ' stop subclassing when exiting edit mode
  TVHook.StopSubclass
End Sub

Private Sub Form_Load()
  ' create an instance of the subclassing control
  Set TVHook = New MsgHook
End Sub

' discard spaces as they are entered by the user

Private Sub TVHook_BeforeMessage(uMsg As Long, wParam As Long, lParam As Long, _
  retValue As Long, Cancel As Boolean)
  If uMsg = WM_CHAR Then
    ' wParam contains the character code
    If wParam = 32 Then Cancel = True
  End If
End Sub