Binaryworld - ReplaceMulti - Multiple string replacements ... [ VB -> String ]

' Perform multiple substitutions in a string
' The first argument is the string to be searched
' The second argument is vbBinaryCompare or vbTextCompare
'   and tells whether the search is case sensitive or not
' The following arguments are pairs of (find, replace) strings
'
' For example:
' Print ReplaceMulti("ABCDEF abcdef", vbBinaryCompare, "AB", "#", "DE", "%")
'     displays "#C%F abcdef"
' Print ReplaceMulti("ABCDEF abcdef", vbTextCompare, "AB", "#", "DE", "%")
'     displays "#C%F #c%f"
'
' The function raises an error if the arguments are unbalanced

Function ReplaceMulti(ByVal Text As String, CompareMethod As VbCompareMethod, _
  ParamArray args() As Variant) As String
  Dim i As Integer
  ' raise Illegal Function Call error if the args()
  ' array contains an odd number of items
  If UBound(args) Mod 2 = 0 Then
    Err.Raise 5
  End If
  ' replace each argument in the pair
  For i = 0 To UBound(args) Step 2
    Text = Replace(Text, args(i), args(i + 1), , , CompareMethod)
  Next
  ReplaceMulti = Text
End Function