Binaryworld - Move Form without title bar (2 different methods) ... [ VB -> Windows ]

You can move a form which has no titlebar by 2 different methods. First method will not show any drag border while second method will show drag borders.

Click here to copy the following block

'//////////////////////////////////////////////////////////
'// Move Form Without Title bar (Method-1: Without drag border)
'//////////////////////////////////////////////////////////

Private Declare Function ReleaseCapture Lib "user32" () As Long
Private Declare Function SetCapture Lib "user32" (ByVal hwnd As Long) As Long
Private bMoving As Boolean ' flag to indicate drag operation
Private sngXStart As Single ' original mouse X offset
Private sngYStart As Single ' original mouse Y offset

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  If Button <> 1 Then Exit Sub  ' only left button
  SetCapture Me.hwnd    ' Get all mouse events
  sngXStart = X      ' save current offset
  sngYStart = Y
  bMoving = True      ' start move
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, _
X As Single, Y As Single)
  If Not bMoving Then Exit Sub  ' ignore if not moving
  ' move form so that new mouse position is same as original
  Me.Move Me.Left - sngXStart + X, Me.Top - sngYStart + Y
End Sub

Private Sub Form_MouseUp(Button As Integer, Shift As Integer, _
X As Single, Y As Single)
  If Not bMoving Then Exit Sub  ' ignore if not moving
  ReleaseCapture      ' stop the moving operation
  bMoving = False
End Sub

And here is the second approach to do the same thing

Click here to copy the following block

'//////////////////////////////////////////////////////////
'// Move Form Without Title bar (Method-2: With Drag border)
'//////////////////////////////////////////////////////////
'Declares for Moving a Form with no Titlebar or Caption
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
    ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Long) As Long

Private Declare Function ReleaseCapture Lib "user32" () As Long

Const WM_NCLBUTTONDOWN = &HA1
Const HTCAPTION = 2

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  If Button <> 1 Then Exit Sub  ' only left button
  ReleaseCapture

  SendMessage hwnd, WM_NCLBUTTONDOWN, _
      HTCAPTION, 0&

  '// Or use:
  ' SendMessage hwnd, WM_SYSCOMMAND, &HF012&, 0&

  bMoving = True      ' start move
End Sub

Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
  If Not bMoving Then Exit Sub  ' ignore if not moving

  ReleaseCapture      ' stop the moving operation
  bMoving = False
End Sub