Binaryworld - Provide a short description of the menu item being highlighted ... [ VB -> Forms & Controls ]

Visual Basic lacks of the capability to display a short description of the menu command being highlighted with the mouse or the keyboard, a feature that all professional applications should have. To add menu descriptions to your program, you must subclass the form and trap the WM_MENUSELECT message.

When this message arrives, you must extract the menu ID from the low-word of wParam, and then use it as an argument to the GetMenuString API function to retrieve the caption of the menu. At this point it is pretty easy to provide a short description of the menu command, on a StatusBar or a Label control:

Note that this technique doesn't work with menu items that point to a submenu.

Click here to copy the following block

' REQUIRES THE MSGHOOK.DLL COMPONENT

Const WM_MENUSELECT = &H11F
Private Declare Function GetMenuString Lib "user32" Alias "GetMenuStringA" _
  (ByVal hMenu As Long, ByVal wIDItem As Long, ByVal lpString As String, _
  ByVal nMaxCount As Long, ByVal wFlag As Long) As Long

Dim WithEvents FormHook As MsgHook

Private Sub Form_Load()
  ' Start form subclassing
  Set FormHook = New MsgHook
  FormHook.StartSubclass hWnd
End Sub

Private Sub FormHook_AfterMessage(ByVal uMsg As Long, ByVal wParam As Long, _
  ByVal lParam As Long, retValue As Long)
  If uMsg = WM_MENUSELECT Then
    ' A menu has been selected (but not clicked yet).
    ' The menu item identifier is in the low-order word of wParam.
    ' The menu handle is in lParam
    Dim menuId As Long, menuCaption As String,
    Dim length As Long, menuDescr As String
    menuId = (wParam And &HFFFF&)
    ' Get the menu caption
    menuCaption = Space$(256)
    length = GetMenuString(lParam, menuId, menuCaption, Len(menuCaption), 0)
    menuCaption = Left$(menuCaption, length)

    ' compare the string with the caption of all menu commands
    Select Case menuCaption
      Case "&New"
        menuDescr = "Create a new file"
      Case "&Open"
        menuDescr = "Open an existing file"
      Case "&Save"
        menuDescr = "Save a file to disk"
      Case "E&xit"
        menuDescr = "Exit the program"
    End Select
    ' display the menu description on a Label control
    lblStatus = menuDescr
  End Select
End Sub