Binaryworld - String operation in vb.net ... [ VB.net -> String ]

The following example uses some of the methods discussed in the Basic String Operations topics to construct a class that performs string manipulations in a manner that might be found in a real-world application. The MailToData class stores the name and address of an individual in separate properties and provides a way to combine the City, State, and Zip fields into a single string for display to the user. Furthermore, the class allows the user to enter the city, state, and ZIP Code information as a single string; the application automatically parses the single string and enters the proper information into the corresponding property.

For simplicity, this example uses a console application with a command-line interface.

Click here to copy the following block

Option Explicit
Option Strict

Imports System
Imports System.IO

Class MainClass

  Public Shared Sub Main()
    Dim MyData As New MailToData()

    Console.Write("Enter Your Name:")
    MyData.Name = Console.ReadLine()
    Console.Write("Enter Your Address:")
    MyData.Address = Console.ReadLine()
    Console.Write("Enter Your City, State, and ZIP Code separated by spaces:")
    MyData.CityStateZip = Console.ReadLine()


    Console.WriteLine("Name: {0}", MyData.Name)
    Console.WriteLine("Address: {0}", MyData.Address)
    Console.WriteLine("City: {0}", MyData.City)
    Console.WriteLine("State: {0}", MyData.State)
    Console.WriteLine("ZIP Code: {0}", MyData.Zip)

    Console.WriteLine("The following address will be used:")

    Console.WriteLine(MyData.Address)
    Console.WriteLine(MyData.CityStateZip)
  End Sub
End Class

Public Class MailToData
  Private strName As String = " "
  Private strAddress As String = " "
  Private strCityStateZip As String = " "
  Private strCity As String = " "
  Private strState As String = " "
  Private strZip As String = " "

  Public Sub New()

  End Sub

  Public Property Name() As String
    Get
      Return strName
    End Get
    Set
      strName = value
    End Set
  End Property

  Public Property Address() As String
    Get
      Return strAddress
    End Get
    Set
      strAddress = value
    End Set
  End Property

  Public Property CityStateZip() As String
    Get
      Return ReturnCityStateZip()
    End Get
    Set
      strCityStateZip = value
      ParseCityStateZip()
    End Set
  End Property

  Public Property City() As String
    Get
      Return strCity
    End Get
    Set
      strCity = value
    End Set
  End Property

  Public Property State() As String
    Get
      Return strState
    End Get
    Set
      strState = value
    End Set
  End Property

  Public Property Zip() As String
    Get
      Return strZip
    End Get
    Set
      strZip = value
    End Set
  End Property

  Private Sub ParseCityStateZip()
    Dim CityIndex As Integer
    Dim StateIndex As Integer
    ' Check for an exception if the user did not enter spaces between
    ' the elements.

    Try

    ' Find index position of the space between
    ' city and state and assign that value to CityIndex.
    CityIndex = strCityStateZip.IndexOf(" ")

    ' Initialize the CityArray to the value of the
    ' index position of of the first white space.
    Dim CityArray(CityIndex) As Char

    ' Copy the city to the CityArray.
    strCityStateZip.CopyTo(0, CityArray, 0, CityIndex)

    ' Find index position of the space between
    ' state and zip and assign that value to CityIndex.
    StateIndex = strCityStateZip.LastIndexOf(" ")

    ' Initialize the StateArray to the length of the state.
    Dim StateArray(StateIndex - CityIndex) As Char

    ' Copy the state to the StateArray.
    strCityStateZip.CopyTo(CityIndex, StateArray, 0, StateIndex - CityIndex)

    ' Initialize the ZipArray to the length of the zip.
    Dim ZipArray(strCityStateZip.Length - StateIndex) As Char

    ' Copy the zip to the ZipArray.
    strCityStateZip.CopyTo(StateIndex, ZipArray, 0, strCityStateZip.Length - StateIndex)

    ' Assign city to the value of CityArray.
    strCity = New String(CityArray)

    ' Trim white spaces, commas, and so on.
    strCity = strCity.Trim(New Char() {" "c, ","c, ";"c, "-"c, ":"c})

    ' Assign state to the value of StateArray.
    strState = New String(StateArray)

    ' Trim white spaces, commas, and so on.
    strState = strState.Trim(New Char() {" "c, ","c, ";"c, "-"c, ":"c})


    ' Assign zip to the value of ZipArray.
    strZip = New String(ZipArray)

    ' Trim white spaces, commas, and so on.
    strZip = strZip.Trim(New Char() {" "c, ","c, ";"c, "-"c, ":"c})

    ' If an exception is encountered, alert the user to enter spaces
    ' between the elements.

    Catch OverflowException As Exception
        Console.WriteLine(ControlChars.Lf + ControlChars.Lf + "You must enter spaces between elements." + ControlChars.Lf + ControlChars.Lf)
    End Try

  End Sub

  Private Function ReturnCityStateZip() As String
    ' Make state uppercase.
    strState = strState.ToUpper()

    ' Put the value of city, state, and zip together in the proper manner.
    Dim MyCityStateZip As String = String.Concat(strCity, ", ", strState, " ", strZip)

    Return MyCityStateZip
  End Function
End Class